[Context Free]手書き風の円

これを参考に。

アルファブレンディングによる手書き風の円の書き方が巧み。
アルファブレンドパラメータは、こういう感じで使うのね。

色々考えてみたけど、あんまり自分風に変えられる点がなかった。

startshape start_rule

background {hue 240 sat 1 b -0.8}

rule start_rule{
3 * {y 7 hue 30} blah{}
}

rule blah {
3 * {x 7 hue 10} blah2 {hue 10 sat 1 s 1 b 1 alpha -1}
}

rule blah2 {
SQUARE { }
blah2 {alpha 0.0001 r 10 x 1 s 0.9995}
}

rule blah2 {
SQUARE { }
blah2 {alpha 0.0001 r 9 x 1 s 0.9995}
}

[Context Free]ぐるぐる

startshape fig5
background { b -1 }

rule fig5 {
4 * {r 90 hue 45 sat 1 s 1} fig4{ hue 100 sat 1 s 1}
}

rule fig4 {
fig3 {r 20}
}


rule fig3 {
fig2 { }
fig3 { s .94 r 25 x .5}
}

rule fig2 {
fig1 { }
fig2 { hue 14 sat 1 s .8 r 14 }
}

rule fig1 {
SQUARE { }
fig1 { s .9 r 5 b .1 x .05}
}

習作シリーズ。

参考はこれ。

久々にContext Freeをやってみる

startshape E

rule E
{
    D{}
    E{s 0.3 r 30}
}

rule D
{
    2 * {r 180}C{}
}

rule C
{
    B{}
    B{f -180}
}

rule B
{
    3 * {r 120 }A {}
}

rule A
{
    CIRCLE{ s 1 .0006}
    A { x .09 sat 1 b 1 hue 1 r 60.21 s .99 }
}

フラクタルアートをまたやりたくなってきて、いじってみた。

ちょっと今まで僕が作ったヤツは、イマイチひねりが足りない感じだったので、ギャラリーにある作品を参考に、カッコよくする手法を学習中。

これを参考に。

[Context Free]太陽

startshape sun

rule sun{
    72*{r 5}curveline{hue 1 sat 1 b 0.7}
}

rule curveline{
    SQUARE{}
    curveline{r 1 s 0.97 y 0.7 hue 2 a -0.02}
}

簡単だけれど、なかなかかっこいい。

[Context Free]SUN from S_Ishimaru on Vimeo.
描画過程ビデオ。

[Context Free]文字と色付けをやってみる

startshape SIMPLE_STR
include i_pix.cfdg

// HELLO書く
rule SIMPLE_STR{
point {}
}

// HELLOを描画して２分岐
rule point {
  H_5by5 {}
  E_5by5 {x 1.2}
  L_5by5 {x 2.4}
  L_5by5 {x 3.6}
  O_5by5{x 4.8}
  point {y 2.0 x -2.5 rotate 10 size 0.6}
  point {y 2.0 x 2.5 rotate -10 size 0.6}
}

とりあえず文字から。
文字関係はi_pix.cfdgに、このドット文字を描く命令が入ってるみたい。
それを利用して、サンプルを若干改変。

startshape COLOR_TREEBALL

rule COLOR_TREEBALL{
    // 緑にして、回転させてみた
    45* {r 8} SPIKE{sat 1 hue 83 s 1 b 0.8}
}

rule SPIKE {
    SQUARE {}
    SPIKE { y 0.95 s 0.97 b 0.02 | hue 0.01}

}

// 0.04/11.01 で発生する分岐
rule SPIKE 0.04 {
    SQUARE {}
    SPIKE { r 25 }
    SPIKE { r -25 }
}

色を付けてみる。
色は、HSB色空間で指定する。

昨日作った木をグルグル回して、色を付けてみた。

Context Freeで遊んでみる

例によってradiumsoftwareさんで見て、面白そうで気になっていたContext Freeでちょっと遊んでみました。

基本的な命令のリファレンスが、わずかA4紙２枚で説明されているドキュメントがあってわかりやすいですね。

examplesから簡単ものを選んで、さらに命令を削ぎ落とし、シンプルなサンプルを３つほど作ってみました。

startshape SIMPLE1

rule SIMPLE1 {
    BL{}
}

rule BL {
    CIRCLE {}
    WL {size 0.95 y 1}
}

rule WL {BL {rotate 10}}

丸が螺旋状に小さく。

startshape SPIKE

rule SPIKE {
    LSPIKE {}
}

rule LSPIKE {
    SQUARE {}
    LSPIKE { y 0.98 s 0.99 r 1}
}

// 0.02/11.01 %で発生する分岐
rule LSPIKE 0.02 {
    SPIKE { r 90 }
    LSPIKE { y 0.98 s 0.99  r 1}
}

カーブした線が細かく分岐。
四角のY座標を移動させながら、大きさを微妙に小さくして、回転させることで、こういう線がかける。

startshape SIMPLE_TREE

rule SIMPLE_TREE{
    SPIKE{}
}

rule SPIKE {
    SQUARE {}
    SPIKE { y 0.95 s 0.97 }
}

// 0.04/11.01 で発生する分岐
rule SPIKE 0.04 {
    SQUARE {}
    SPIKE { r 35 }
    SPIKE { r -35 }
}

最後に、ちょっと慣れてきたので作ってみた木。

いやー、なかなか面白いですね、これ。
もうちょっと使ってみたいところ。